|
| 1 | +/* |
| 2 | + * Copyright 2025 elementary, Inc. (https://elementary.io) |
| 3 | + * SPDX-License-Identifier: GPL-3.0-or-later |
| 4 | + * |
| 5 | + * Authored by: Leonhard Kargl <[email protected]> |
| 6 | + */ |
| 7 | + |
| 8 | +public class Gala.Icon : Clutter.Actor { |
| 9 | + private class GIconSource : Object, IconSource { |
| 10 | + private static Gtk.IconTheme icon_theme = new Gtk.IconTheme () { |
| 11 | + theme_name = "elementary" |
| 12 | + }; |
| 13 | + |
| 14 | + public GLib.Icon gicon { get; construct; } |
| 15 | + |
| 16 | + public GIconSource (GLib.Icon gicon) { |
| 17 | + Object (gicon: gicon); |
| 18 | + } |
| 19 | + |
| 20 | + public string? get_cache_key (int size, float scale) { |
| 21 | + var gicon_str = gicon.to_string (); |
| 22 | + return gicon_str != null ? "gicon-%s-%d-%f".printf (gicon_str, size, scale) : null; |
| 23 | + } |
| 24 | + |
| 25 | + public Gdk.Pixbuf create_pixbuf (int size, float scale) throws Error { |
| 26 | + var icon_paintable = icon_theme.lookup_by_gicon (gicon, size, (int) Math.ceilf (scale), NONE, 0); |
| 27 | + |
| 28 | + var file = icon_paintable?.file; |
| 29 | + if (file == null) { |
| 30 | + throw new IOError.FAILED ("Icon paintable has no file"); |
| 31 | + } |
| 32 | + |
| 33 | + return new Gdk.Pixbuf.from_stream_at_scale (file.read (), -1, get_texture_size (size, scale), true); |
| 34 | + } |
| 35 | + } |
| 36 | + |
| 37 | + private class ResourceIconSource : Object, IconSource { |
| 38 | + public string path { get; construct; } |
| 39 | + |
| 40 | + public ResourceIconSource (string path) { |
| 41 | + Object (path: path); |
| 42 | + } |
| 43 | + |
| 44 | + public string? get_cache_key (int size, float scale) { |
| 45 | + return "%s-%d".printf (path, get_texture_size (size, scale)); |
| 46 | + } |
| 47 | + |
| 48 | + public Gdk.Pixbuf create_pixbuf (int size, float scale) throws Error { |
| 49 | + return new Gdk.Pixbuf.from_resource_at_scale (path, -1, get_texture_size (size, scale), true); |
| 50 | + } |
| 51 | + } |
| 52 | + |
| 53 | + private interface IconSource : Object { |
| 54 | + public abstract string? get_cache_key (int size, float scale); |
| 55 | + /** |
| 56 | + * Should look up the icon for the given size (e.g. if there are more detailed icons |
| 57 | + * for larger sizes) and return a texture of size * scale. |
| 58 | + */ |
| 59 | + public abstract Gdk.Pixbuf create_pixbuf (int size, float scale) throws Error; |
| 60 | + |
| 61 | + protected static int get_texture_size (int size, float scale) { |
| 62 | + return (int) Math.ceilf (size * scale); |
| 63 | + } |
| 64 | + } |
| 65 | + |
| 66 | + private static HashTable<string, Gdk.Pixbuf> icon_pixbufs = new HashTable<string, Gdk.Pixbuf> (str_hash, str_equal); |
| 67 | + |
| 68 | + public int icon_size { get; construct set; } |
| 69 | + public float monitor_scale { get; construct set; } |
| 70 | + |
| 71 | + public string resource_path { set { source = new ResourceIconSource (value); } } |
| 72 | + public GLib.Icon gicon { set { source = new GIconSource (value); } } |
| 73 | + |
| 74 | + private IconSource _source; |
| 75 | + private IconSource source { |
| 76 | + get { return _source; } |
| 77 | + set { |
| 78 | + _source = value; |
| 79 | + load_pixbuf (); |
| 80 | + } |
| 81 | + } |
| 82 | + |
| 83 | + public Icon (int icon_size, float monitor_scale) { |
| 84 | + Object (icon_size: icon_size, monitor_scale: monitor_scale); |
| 85 | + } |
| 86 | + |
| 87 | + public Icon.from_resource (int icon_size, float monitor_scale, string resource_path) { |
| 88 | + Object (icon_size: icon_size, monitor_scale: monitor_scale, resource_path: resource_path); |
| 89 | + } |
| 90 | + |
| 91 | + construct { |
| 92 | + notify["icon-size"].connect (load_pixbuf); |
| 93 | + notify["monitor-scale"].connect (load_pixbuf); |
| 94 | + resource_scale_changed.connect (load_pixbuf); |
| 95 | + } |
| 96 | + |
| 97 | + private void load_pixbuf () { |
| 98 | + var actor_size = Utils.scale_to_int (icon_size, monitor_scale); |
| 99 | + set_size (actor_size, actor_size); |
| 100 | + |
| 101 | + var scale = monitor_scale * get_resource_scale (); |
| 102 | + |
| 103 | + try { |
| 104 | + var pixbuf = get_pixbuf (icon_size, scale); |
| 105 | + content = new Gala.Image.from_pixbuf_with_size (actor_size, actor_size, pixbuf); |
| 106 | + |
| 107 | + set_background_color (null); |
| 108 | + } catch (Error e) { |
| 109 | + critical ("Could not load icon pixbuf: %s", e.message); |
| 110 | + background_color = { 255, 0, 0, 255 }; |
| 111 | + } |
| 112 | + } |
| 113 | + |
| 114 | + private Gdk.Pixbuf get_pixbuf (int size, float scale) throws Error { |
| 115 | + var cache_key = source.get_cache_key (size, scale); |
| 116 | + |
| 117 | + if (cache_key == null) { |
| 118 | + return source.create_pixbuf (size, scale); |
| 119 | + } |
| 120 | + |
| 121 | + if (!(cache_key in icon_pixbufs)) { |
| 122 | + icon_pixbufs[cache_key] = source.create_pixbuf (size, scale); |
| 123 | + } |
| 124 | + |
| 125 | + return icon_pixbufs[cache_key]; |
| 126 | + } |
| 127 | +} |
0 commit comments